// The Seekers Version 2.0
//
// Wally Glutton
// http://www.stungeye.com
//
// Seekers set out to search for gold. If found, they will remember it's location
// and begin transporting the gold home. Each time they arrive at the goldmine they
// use their telepathy to inform one other seeker (choosen at random) of the location.
//
// Released under Creative Commons Attribution-ShareAlike 1.0
// http://creativecommons.org/licenses/by-sa/1.0/ 


// GOLDMINE CONSTANTS
int NUMGOLDMINES = 15;
int MINGOLDMINES = 1;
int MAXGOLDSIZE = 25;
int INITIALGOLD = 1000; 

// HOME CONSTANTS
int HOMESIZE = 17;

// SEEKER CONSTANTS
int NUMSEEKERS = 50000;
int MINSEEKERS = 50;
int SEEKERSIZE = 3;
float TRACKFACTOR = 0.1;
float TRACKFACTORMARGIN = 0.05;
int SEEKERSIGHT = 8;
int NUMFRIENDS = 200;
int MINNUMFRIENDS = 0;
int CALLRANGE = 400;
int MINCALLRANGE = 25;
boolean SKIPFOUNDCHECK = true;

// COLOUR CONSTANTS
int GOLDCOLOUR = #FFFF00;
int HOMECOLOUR = #00FF00;
int FOUNDCOLOUR = #FF00FF;
int SEEKCOLOUR = #0000FF;
int PAYLOADCOLOUR = #FF0000;

GoldMine[] goldMines;
Home home;
Seeker[] seekers;

int currentNumSeekers = 250;
int currentGoldMines = 1;
int currentCallRange = 100;
int currentNumFriends = 5;

int seekerLandWidth,seekerLandHeight;

BFont overBurnFont;
BFont silkFont;
boolean paused = false;
boolean refresh = true;

int numHandles = 4;
Handle[] handles;

void setup()
{
  //smooth();
  //framerate(12);
  size(600,400);
  
  seekerLandWidth = width - 200;
  seekerLandHeight = height;
    
  goldMines = new GoldMine[NUMGOLDMINES];
  newGoldMines();
  newHome();
  seekers = new Seeker[NUMSEEKERS];
  newSeekers();
  
  overBurnFont = loadFont("Overload_Burn.vlw.gz");
  silkFont = loadFont("Silkscreen.vlw.gz");
    
  makeHandles();
  
}

void loop()
{
  int i = 0;
  
  if (refresh)
    background(0);
  else
  { 
    noStroke();
    fill(0);
    rect(400,0,600,400);
  }
  home.processTurn();
  
  if (!paused)
    for(i=0; i < NUMSEEKERS; i++)
        seekers[i].processTurn();
  
  for(i=0; i < currentGoldMines; i++)
  {  
    if (goldMines[i].getContent() <= 0)
    {
      newGoldMine(i);
    }
    
    goldMines[i].display();
  }
    
  home.display();
  
  for(i=0; i < NUMSEEKERS; i++)
    seekers[i].display();
    
  displayMenu();
  
  for (i=0; i<numHandles; i++)
  {
    handles[i].update();
    handles[i].display();
  }
}

// HELPER FUNCTIONS

void makeHandles()
{
  
  handles = new Handle[numHandles];

  // NUM SEEKERS handle
  handles[0] = new Handle(seekerLandWidth, 90+(0)*65, 10, true, 10, MINSEEKERS, NUMSEEKERS, currentNumSeekers, seekerLandWidth+11, 90+(0)*65-15, handles);  
  
  // CALL RANGE handle
  handles[1] = new Handle(seekerLandWidth, 90+(1)*65, 10, true, 10, MINCALLRANGE, CALLRANGE, currentCallRange, seekerLandWidth+11, 90+(1)*65-15, handles);  
  
  // NUM FRIENDS handle
  handles[2] = new Handle(seekerLandWidth, 90+(2)*65, 10, true, 10, MINNUMFRIENDS, NUMFRIENDS, currentNumFriends, seekerLandWidth+11, 90+(2)*65-15, handles);  
  
  // NUM GOLD MINES handle
  handles[3] = new Handle(seekerLandWidth, 90+(3)*65, 10, true, 10, MINGOLDMINES, NUMGOLDMINES, currentGoldMines, seekerLandWidth+11, 90+(3)*65-15, handles);

}

void displayMenu()
{
  stroke(255) ;
  line(seekerLandWidth,0,seekerLandWidth,height);

  fill(255);
  textFont(overBurnFont,30);
  text("The Seekers!",seekerLandWidth+11,25);
  textFont(silkFont,14);
  
  int place = 35;
  line(seekerLandWidth,place,width,place);
  place += 5;
  line(seekerLandWidth,place,width,place);  
  place += 20;
  text("Number of Seekers:", seekerLandWidth+11,place);
  place += 15;
  //text(NUMSEEKERS,seekerLandWidth+11,place);
  place += 30;
  line(seekerLandWidth,place,width,place);
  place += 20;
  text("Call Radius:",seekerLandWidth+11,place);
  place += 15;
  //text(CALLRANGE,seekerLandWidth+11,place);
  place += 30;
  line(seekerLandWidth,place,width,place);
  place += 20;
  text("Number of Friends:",seekerLandWidth+11,place);
  place += 15;
  //text(NUMFRIENDS,seekerLandWidth+11,place);
  place += 30;
  line(seekerLandWidth,place,width,place);
  place += 20;
  text("Number of Mines:",seekerLandWidth+11,place);
  place += 15;
  //text(NUMGOLDMINES,seekerLandWidth+11,place);
  place += 30;
  line(seekerLandWidth,place,width,place);
  place += 5;
  line(seekerLandWidth,place,width,place);
  place += 25;
  text("Wally Glutton 2004",seekerLandWidth+11,place);
  place += 15;
  text("www.stungeye.com",seekerLandWidth+11,place);
  place += 25;
  text("Learn to question.",seekerLandWidth+11,place);
  place += 15;
  text("Question to learn.",seekerLandWidth+11,place);
}

void newSeekers()
{
  for (int i = 0; i < NUMSEEKERS; i++)
  {
    newSeeker(i);
  }
  
  for (int i = currentNumSeekers; i < NUMSEEKERS; i++)
  {
    seekers[i].deactivate();
  }
}

void newSeeker(int num)
{
  seekers[num] = new Seeker((int)home.homeLocation.x,(int)home.homeLocation.y);
}

void resetSeekers()
{
   for (int i = 0; i < NUMSEEKERS; i++)
  {
    seekers[i].reset();
  }
}

void newGoldMines()
{
  for (int i = 0; i < NUMGOLDMINES; i++)
    newGoldMine(i);
    
  for (int i = currentNumSeekers; i < NUMGOLDMINES; i++)
      goldMines[i].deactivate();
}

void newGoldMine(int num)
{
  int initialX = (int)random(MAXGOLDSIZE,seekerLandWidth-MAXGOLDSIZE);
  int initialY = (int)random(MAXGOLDSIZE,seekerLandHeight-MAXGOLDSIZE);
  goldMines[num] = new GoldMine(INITIALGOLD,initialX,initialY);
}

void newHome()
{
  int initialX = (int)random(HOMESIZE,seekerLandWidth-HOMESIZE);
  int initialY = (int)random(HOMESIZE,seekerLandHeight-HOMESIZE);
      
  home = new Home(initialX,initialY);  
}

// CLASSES

class Seeker
{
  Location seekerLocation;
  Location potentialGoldLocation;
  boolean seeking = true;
  boolean payload = false;
  boolean foundGold = false;
  boolean active;

  Seeker(int initialX, int initialY)
  {
    seekerLocation = new Location(initialX, initialY);
    potentialGoldLocation = new Location(initialX, initialY);
    active = true;
  }
  
  void deactivate()
  {
    active = false;
  }
  
  void processTurn()
  {
    if (!active)
      return;
      
    if (seekerLocation.equals(home.homeLocation))
    {
      if (!foundGold)
      {
        home.newLocation();
        potentialGoldLocation.setTo(home.goldLocation);
      }
      seeking = true;
      payload = false;
    }
    
    if (seekerLocation.equals(potentialGoldLocation))
    {
      boolean foundSome = false;
       
      for (int i = 0; i < currentGoldMines; i++)
      {     
        if ((seekerLocation.equals(goldMines[i].goldLocation)) && (goldMines[i].active))
        {
          for (int j = 0; j < currentNumFriends; j++)
          {
            int contactSeeker = (int)(random(currentNumSeekers-1));
            if ((!seekers[contactSeeker].foundGold || SKIPFOUNDCHECK) && (!seekers[contactSeeker].payload) && (seekers[contactSeeker].seekerLocation.withinRadius(seekerLocation,currentCallRange)))
            {
              
              seekers[contactSeeker].potentialGoldLocation.setTo(potentialGoldLocation);
              seekers[contactSeeker].foundGold = true;
            }
          }
          
          goldMines[i].removeGold();
          payload = true;
          foundGold = true;
          seeking = false;
          foundSome = true;
          break;
        }
      }
  
      if (!foundSome)
      {
        home.newLocation();
        potentialGoldLocation.setTo(home.goldLocation);
        reset();
      }

    }
   
    for (int i = 0; i < currentGoldMines; i++)
      if ((seekerLocation.withinRadius(goldMines[i].goldLocation,SEEKERSIGHT+(SEEKERSIZE/2)+(goldMines[i].getRadius()/2))) && (goldMines[i].active))
      {
        potentialGoldLocation.setTo(goldMines[i].goldLocation);
        break;
      }
   
    if (seeking)
      seekerLocation.moveTowards(potentialGoldLocation);
    else
      seekerLocation.moveTowards(home.homeLocation);
    
  }
  
  void display()
  {
    if (!active)
      return;
      
    noStroke();
    color seekerColour;
    
    if (payload)
      seekerColour = PAYLOADCOLOUR;
    else if (foundGold)
      seekerColour = FOUNDCOLOUR;
    else
      seekerColour = SEEKCOLOUR;
    
    fill(seekerColour);
    ellipseMode(CENTER_DIAMETER);
    ellipse(seekerLocation.x,seekerLocation.y,SEEKERSIZE,SEEKERSIZE);
    ellipseMode(CORNER);
  }
  
  void reset()
  {
    payload = false;
    foundGold = false;
    seeking = true;
  }
  
}

class GoldMine
{
  int goldContent;
  int maxContent;
  Location goldLocation;
  boolean active;
  
  GoldMine(int initialContent, int initialX, int initialY)
  {
    maxContent = goldContent = initialContent;
    goldLocation = new Location(initialX, initialY);
    active = true;
    
  }
  
  void deactivate()
  {
    goldContent = 0;
    active = false;
  }
  
  void setGoldContent(int content)
  {
    maxContent = goldContent = content;
  }
  
  void removeGold()
  {
    goldContent--;
  }
  
  void display()
  {
    noStroke();
    color goldColour = GOLDCOLOUR;
    fill(goldColour);
    float goldSize = MAXGOLDSIZE * goldContent / maxContent;
    ellipseMode(CENTER_DIAMETER);
    ellipse(goldLocation.x,goldLocation.y,goldSize,goldSize);
    ellipseMode(CORNER);
  }
  
  int getContent()
  {
    return goldContent;
  }
  
  int getRadius()
  {
    return (int)MAXGOLDSIZE * goldContent / maxContent;
  }

}

class Home
{
  Location homeLocation;
  Location goldLocation;
  boolean goldLocationKnown = false;
  
  Home(int initialX, int initialY)
  {
    homeLocation = new Location(initialX,initialY);
    goldLocation = new Location(initialX,initialY);
  }
  
  void processTurn()
  {
  }

  void newLocation()
  {
    if (!goldLocationKnown)
      {
        goldLocation.x = (int)random(SEEKERSIZE,seekerLandWidth-SEEKERSIZE);
        goldLocation.y = (int)random(SEEKERSIZE,seekerLandHeight-SEEKERSIZE);
      }
  }
      
  void display()
  {
    rectMode(CENTER_DIAMETER);
    noStroke();
    color homeColour = HOMECOLOUR;
    fill(homeColour);
    rect(homeLocation.x,homeLocation.y,HOMESIZE,HOMESIZE);
    rectMode(CORNER);
  }  

}

class Location
{
  float x;
  float y;
  float trackFactorAdjustedX;
  float trackFactorAdjustedY;
  
  Location(int initialX, int initialY)
  {
    x = (float)initialX;
    y = (float)initialY;
    trackFactorAdjustedX = TRACKFACTOR;
    trackFactorAdjustedY = TRACKFACTOR;
  }
  
  void setTo(Location newLocation)
  {
    x = newLocation.x;
    y = newLocation.y;
  }
  
  boolean equals(Location compareLocation)
  {
    return withinRadius(compareLocation,1);
  }
  
  void moveTowards(Location destination)
  {
    trackFactorAdjustedX = TRACKFACTOR + random(-TRACKFACTORMARGIN,TRACKFACTORMARGIN);
    trackFactorAdjustedY = TRACKFACTOR + random(-TRACKFACTORMARGIN,TRACKFACTORMARGIN);
    
    float xMove = ((x - destination.x) * trackFactorAdjustedX);
    float yMove = ((y - destination.y) * trackFactorAdjustedY);

    x -= xMove;
    y -= yMove;    
  }

  boolean withinRadius(Location otherLocation, float radius)
  {
    float distance = sqrt( sq( x-otherLocation.x ) + sq( y-otherLocation.y ) );

    if (distance <= radius)
      return true;
    else
      return false;
  }
  
  
  void addError(float percent)
  {
    x *= percent;
    y *= percent; 
  }
  
}

void mouseReleased()
{
  for(int i=0; i<numHandles; i++)
  {
    handles[i].release();
  }
  
  if (paused)
  {
    if (handles[0].changed) // NUM SEEKERS handle
    {
      if (handles[0].currentValue > currentNumSeekers)
      { 
        for(int i = currentNumSeekers; i < handles[0].currentValue; i++)
        {
          newSeeker(i); 
        }
      }
      else if (handles[0].currentValue < currentNumSeekers)
      {
        for (int i = currentNumSeekers-1; i >= handles[0].currentValue; i--)
        {
          seekers[i].deactivate();
        }
      }
      currentNumSeekers = handles[0].currentValue;
    }
    else if (handles[1].changed) // CALL RADIUS handle
    {
      currentCallRange = handles[1].currentValue;
    }
    else if (handles[2].changed) // NUM FRIENDS handle
    {
      currentNumFriends = handles[2].currentValue;
    }
    else if (handles[3].changed) // NUM MINES handle
    {
      //println("Handles:" + handles[3].currentValue + " current:" + currentGoldMines);
      if (handles[3].currentValue > currentGoldMines)
      { 
        for(int i = currentGoldMines; i < handles[3].currentValue; i++)
        {
          newGoldMine(i);
        }
      }
      else if (handles[3].currentValue < currentGoldMines)
      {
        for (int i = currentGoldMines-1; i >= handles[3].currentValue; i--)
        {
          goldMines[i].deactivate();
        }
      }
      currentGoldMines = handles[3].currentValue;
    }
    paused = false;
  }
  
}

// Handles 2

// Variation on Handles
// by REAS <http://www.groupc.net>

// Click and drag the white boxes to change their position.

// Created 10 February 2003
// Variation 15 January 2004 by K Pfeiffer
// Upper half of the handles grab at the centerpoint
// Lower half use centerpoint to mouseX offset so handles don't 'jump' when you grab them
//
// Modified April 2004 for use with the Seekers by Wally Glutton 

class Handle
{
  int x, y;
  int minValue, maxValue;
  int currentValue;
  int xText, yText;
  int boxx, boxy;
  int length;
  int maxLength;
  int origLength;
  int size;
  boolean over;
  boolean press;
  boolean locked = false;
  boolean otherslocked = false;
  int offsetMouseX;              // difference between mouseX and handle center when mousePressed
  Handle[] others;
  boolean isCircle;
  boolean changed;

  Handle(int _x, int _y, int _l, boolean c, int _s, int _minValue, int _maxValue, int startValue, int _xText, int _yText, Handle[] o)
  {
    x = _x;
    y = _y;
    minValue = _minValue;
    maxValue = _maxValue;
    currentValue = startValue;
    xText = _xText;
    yText = _yText;
    size = _s;
    maxLength = width-size-x-20;
    length = (int)((float)((currentValue*maxLength)-(minValue*maxLength)))/(maxValue-minValue) +10;
    origLength = 10;
    changed = false;
    boxx = x+length - size/2;
    boxy = y - size/2;
    others = o;
    isCircle = c;
    

  }

  void update()
  {
    boxx = x+length;
    boxy = y - size/2;
    changed = false;

    for(int i=0; i<others.length; i++) {
      if(others[i].locked == true) {
        otherslocked = true;
        break;
      } else {
        otherslocked = false;
      }
    }

    if(otherslocked == false) {
      over();
      press();
    }

    if(press) {

      // length = lock(mouseX-width/2-size/2, 0, width/2-size-1);       // should use object variable x instead of width/2
      length = lock(mouseX+offsetMouseX-x-size/2, origLength, width-x-size-10);   // allow for offset of curser in handle
      float scaleBy = (float)(length-10)/maxLength;
      currentValue = (int)(minValue + (maxValue-minValue)*scaleBy);
      changed = true;
      
    }
  }

  void over()
  {

    if(isCircle == true) {
      if(overCircle(boxx, boxy, size)) {
        over=true;
      } else {
        over= false;
      }
    } else if(overRect(boxx, boxy, size, size)) {
      over = true;
    } else {
      over = false;
    }
  }

  void press()
  {
    if(over && mousePressed || locked) {
      if(locked != true && y > height/2) {
        offsetMouseX = -(mouseX-(x+length+size/2));   // difference between mouseX on press and center of handle
      }                                               // keeps handle center from 'jumping' to curser hotspot
      press = true;
      locked = true;
      paused = true;
    } else {
      press = false;
      //paused = false;
    }
  }

  void release()
  {
    locked = false;
  }

  void display()
  {
    stroke(255);
    line(x, y, x+length, y);
    fill(255);
    stroke(0);
    if(isCircle == true) {
      ellipse(boxx, boxy, size, size);
    } else {
      rect(boxx, boxy, size, size);
    }
    if(over || press) {
     
        line(boxx, boxy, boxx+size, boxy+size);
        line(boxx, boxy+size, boxx+size, boxy);
     
    }
    textFont(silkFont,14);
    //text(temp,xText,yText);
    text(currentValue,xText,yText);
  }
}

boolean overRect(int x, int y, int width, int height)
{
  if (mouseX >= x && mouseX <= x+width &&
  mouseY >= y && mouseY <= y+height) {
    return true;
  } else {
    return false;
  }
}

boolean overCircle(int x, int y, int diameter)
{
  float offsetX = x + diameter/2 - mouseX;
  float offsetY = y + diameter/2 - mouseY;
  if(sqrt(sq(offsetX) + sq(offsetY)) < diameter/2 ) {
    return true;
  } else {
    return false;
  }
}

int lock(int val, int minv, int maxv)
{
  return  min(max(val, minv), maxv);
}


void mousePressed() {

   if (overRect(0,0,400,400)) // Reset if user clicks on the seeker field.
   {
     newGoldMines();
     newHome();
     resetSeekers();
   }
   else if (overRect(400,305,600,400))
   {
     refresh = !refresh;
   }
}